home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload Trio 2 / Shareware Overload Trio Volume 2 (Chestnut CD-ROM).ISO / dir26 / epi601_3.zip / FILES11.EXE / TIME.PGM < prev    next >
Text File  |  1994-08-22  |  9KB  |  245 lines
  1. *=============================== TIME.PGM ===================================
  2. *    Surveillance Information System Demo: updating time data ...
  3. *
  4. * Epi Info program that reads communicable disease surveillance files, 
  5. * produces disease specific aggregated files for use in graphic package. 
  6. * It outputs ASCII comma delimited files that can be retrieved in any 
  7. * graphic software such as Harvard graphics (DOS 2,3, or Windows) or 
  8. * Freelance graphics, using templates.
  9. *
  10. * READS        : SUMXX   .REC x (YEARBACK + 1)
  11. * USES        :
  12. * PRODUCES    : XXXXX   .DAT
  13. *
  14. * LAST UPDATE 06/06/94 Denis Coulombier
  15. *
  16. *============================================================================
  17.  
  18.  
  19. *============================== Initialization section ======================
  20. SET IGNORE=OFF SPLIT=OFF NOECHO=ON COLOR = 31 30 112
  21. CLS
  22.  
  23. *-------------------- Global variables declarations ---------------------
  24. DEFINE HGVERSION  #     GLOB 3
  25. * HGVERSION corresponds to the Harvard Graphic version used. 2 for 2.x
  26. * and 3 for version 3. Both version treat differently ASCII data
  27. * when importing.
  28.  
  29. DEFINE CURYEAR    ##    GLOB 
  30. IMMEDIATE CURYEAR = SYSTEMDATE[7,2]
  31. * The current year defaults to the system year. You can change this by
  32. * commenting out last line and changing the declaration 
  33. * of this year as follows: DEFINE CURYEAR ## GLOB 93
  34.  
  35. DEFINE CURDIS ____________________ GLOB
  36. * Hold the name of the current disease for updating title in HG3
  37.  
  38. DEFINE DUMYEAR    ##    GLOB @CURYEAR
  39. DEFINE YEARBACK   #     GLOB 4
  40. * YEARBACK specifies the additional number of years you want to consider for 
  41. * building historical trends. If YEARBACK = 3, then 4 summary files will be 
  42. * open since it requires four files to have the past 156 weeks (3 years)
  43.  
  44. DEFINE FILES STRING WIDTH=50 GLOB "SUM@CURYEAR "
  45. * Holds the name of the summary files to open
  46.  
  47. DEFINE COUNTER    ##    GLOB
  48. DEFINE CUREVENT   ##### GLOB
  49. * Disease under consideration
  50.  
  51. DEFINE LASTWEEK   ##    GLOB
  52. * last week of the current year
  53.  
  54. *-------------------- Checks last week of CURYEAR ---------------------------
  55. READ SUM@CURYEAR
  56. IF MMWRWK > COUNTER THEN COUNTER = MMWRWK
  57. * Checks the latest MMWR week entered and loads it into LASTWEEK
  58. GOTO PROG_SCR
  59. ECHO
  60. ECHO                   Current dataset:  SUM@CURYEAR
  61. ECHO
  62. ECHO             Calculating the last MMWRWK entered in 19@THISYEAR             
  63. ECHO
  64. ECHO
  65. SET NOECHO=ON
  66. PROCESS
  67. CLS
  68. SET NOECHO=ON
  69. IMMEDIATE LASTWEEK = COUNTER
  70. *-------------------- Determines files to be opened ---------------------------
  71.  
  72. IMMEDIATE COUNTER = YEARBACK
  73. :LOOPFILE
  74.   IMMEDIATE DUMYEAR = DUMYEAR - 1
  75.   IMMEDIATE COUNTER = COUNTER - 1
  76.   IMMEDIATE FILES = FILES + "SUM@DUMYEAR "
  77.   IMMEDIATE IF COUNTER > 0 THEN \
  78. GOTO LOOPFILE
  79. * This loop decrement the year YEARBACK times, and append the name of the 
  80. * file to FILES which will be READ later
  81. *===========================End Initialization section ======================
  82.  
  83.  
  84. *============================ Main Program section ===========================
  85. * This main program section contains code for selecting disease, and then
  86. * calls a sub routine to process the file.
  87. * 
  88. * This "structured" approach allows easy maintenance of the code since
  89. * only one copy of the code for any specific disease is necessary
  90. *
  91. * The only thing necessary to add a disease in the list are the 2 statements
  92. * IMMEDIATE CUREVENT=XXXXX
  93. * GOTO PROC_DISEAS
  94. * Customized to the disease code of interest
  95.  
  96. *--- Salmonellosis ---
  97. IMMEDIATE CUREVENT=11000
  98. GOTO PROC_DISEAS
  99.  
  100. *--- Gonorrhea ---
  101. IMMEDIATE CUREVENT=10280
  102. GOTO PROC_DISEAS
  103.  
  104. *--- Hepatitis B ---
  105. IMMEDIATE CUREVENT=10100
  106. GOTO PROC_DISEAS
  107.  
  108. *--- Measles ---
  109. IMMEDIATE CUREVENT=10500
  110. GOTO PROC_DISEAS
  111.  
  112. *--- Hemophilus Influenzae ---
  113. IMMEDIATE CUREVENT=10590
  114. GOTO PROC_DISEAS
  115.  
  116. * Clean up and QUIT
  117. RUN CONFIG.EPI
  118. READ STATUS
  119. IF REPORTCODE = 4 THEN UPDATEDATE = SYSTEMDATE
  120. IF REPORTCODE = 4 THEN UPDATETIME = SYSTEMTIME
  121. ERASE ~.REC
  122. ROUTE ~.REC
  123. WRITE RECFILE REPORTNAME REPORTCODE UPDATEDATE UPDATETIME
  124. ROUTE SCREEN
  125. READ ~.REC
  126. ERASE STATUS.REC
  127. CLOSE ~.REC
  128. RENAME ~.REC STATUS.REC
  129. ERASE ~.REC
  130. QUIT
  131. *=========================End Main Program section ===========================
  132.  
  133. *========================= Sub routine: PROC_DISEAS ========================== 
  134. * This section creates a summary file with PLACE and PERSON specific 
  135. * information, aggregated by TIME characteristics.
  136. * The file generated will be used by GRAPHIC software to display data
  137. * This example uses salmonellosis notification (EVENT=11000)
  138. * Any disease can be added by copying the disease specific section
  139. * and changing the IMMEDIATE CUREVENT statement
  140. *------------------------- Data section -------------------------------------
  141. :PROC_DISEAS
  142. READ @FILES
  143. DEFINE SERIE ###
  144. * Serial holds the week number of the past YEARBACK*52 weeks
  145.  
  146. SERIE = MMWRWK - LASTWEEK + ((YEARBACK - (CURYEAR - YEAR)) * 52)
  147. * Numbers the week from 1 to YEABACK * 52, corresponding to the 
  148. * last YEARBACK number of years of data
  149.  
  150. SELECT SERIE > 0 AND <= (YEARBACK * 52) 
  151. SELECT EVENT = CUREVENT
  152. ** SELECT any optional PLACE characteristics such as county
  153.  
  154. *------------------------- Process section ----------------------------------
  155. ERASE ~.REC
  156. ROUTE ~.REC
  157. GOTO PROG_SCR
  158. ECHO
  159. ECHO           Routing output to a temporary file ~.REC
  160. ECHO
  161. ECHO             Current dataset: @FILES
  162. ECHO               Current event: @CUREVENT
  163. ECHO                Current Week: @LASTWEEK 
  164. ECHO                Current year: 19@CURYEAR
  165. ECHO
  166. SET NOECHO=ON
  167. OUTPUT SUMFREQ COUNT SERIE
  168. SET NOECHO=ON
  169. CLS
  170. * 2nd level of aggregation, by week number, in a temporary file
  171.  
  172. READ DISEASES
  173. IF EVENT = CUREVENT THEN CURDIS = DISEASE
  174. PROCESS
  175. ERASE @CUREVENT.DAT
  176. ROUTE @CUREVENT.DAT
  177. IMMEDIATE IF HGVERSION = 2 THEN TYPE ",Up to Week # @LASTWEEK of 19@CURYEAR"
  178. IMMEDIATE IF HGVERSION = 3 THEN \
  179. TYPE "Notifications of @CURDIS\nState of Michigan, as of Week # @LASTWEEK, 19@CURYEAR"
  180. * In Harvard graphics 2.x, the first record of an ASCII comma delimited
  181. * file may be used to update the legend. In Harvard 3, every attributes of 
  182. * the graph may be updated from an ASCII file, including the title,
  183. * axis title. If you use HG3, you can add as many TYPE statement as you
  184. * wish. You will have to customize the link in the IMPORT ASCII DELIMITED
  185. * feature of HG3
  186.  
  187. READ WEEK.REC
  188. RELATE SERIE ~.REC
  189. * WEEK.REC file has only one variable, SERIE, taking values from 1 to 400
  190. * By relating from this file to the file newly aggregated, we ensure
  191. * that all weeks are represented whether or not cases were notified. 
  192. * OUTPUT SUMFREQ does not produce one record for weeks not represented in 
  193. * the data file. These missing weeks are recoded from missing to 0 
  194. * (RECODE COUNT .=0)
  195.  
  196. SELECT SERIE > 0 AND <= (YEARBACK * 52) 
  197. RECODE COUNT .=0
  198.  
  199. GOTO PROG_SCR
  200. ECHO
  201. IMMEDIATE IF HGVERSION = 2 THEN \
  202. ECHO    Routing output in ASCII format for Harvard Graphics 2.x  ELSE \
  203. ECHO    Routing output in ASCII format for Harvard Graphics 3.x 
  204. ECHO
  205. ECHO             Current dataset: @FILES
  206. ECHO               Current event: @CUREVENT
  207. ECHO                Current Week: @CURWEEK 
  208. ECHO                Current year: 19@CURYEAR
  209. ECHO
  210. SET NOECHO=ON
  211. WRITE SERIE,",",COUNT
  212. SET NOECHO=ON
  213. CLS
  214. * Output 2 series in the .DAT file, separated by a comma
  215. *    1,   12
  216. *    2,    4
  217. *    3,    8
  218. * .....
  219. ROUTE SCREEN
  220. RETURN
  221. *======================End Sub routine: PROC_DISEAS ========================== 
  222.  
  223. *========================= Sub routine: PROG_SCR ============================= 
  224. :PROG_SCR
  225. CLS
  226. SET NOECHO=OFF
  227. ECHO ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
  228. ECHO ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
  229. ECHO ▓▓▓▓▓▓▓╔════════════════════════════════════════════════════════════════╗▓▓▓▓▓▓
  230. ECHO ▓▓▓▓▓▓▓║                                                                ║░▓▓▓▓▓
  231. ECHO ▓▓▓▓▓▓▓║                    N E T S S    R E P O R T S                  ║░▓▓▓▓▓
  232. ECHO ▓▓▓▓▓▓▓║                                                                ║░▓▓▓▓▓
  233. ECHO ▓▓▓▓▓▓▓╠════════════════════════════════════════════════════════════════╣░▓▓▓▓▓
  234. ECHO ▓▓▓▓▓▓▓║                                                                ║░▓▓▓▓▓
  235. ECHO ▓▓▓▓▓▓▓║     »  Please be patient ........                              ║░▓▓▓▓▓
  236. ECHO ▓▓▓▓▓▓▓║                                                                ║░▓▓▓▓▓
  237. ECHO ▓▓▓▓▓▓▓║     »  Running report TIME.PGM                                 ║░▓▓▓▓▓
  238. ECHO ▓▓▓▓▓▓▓║                                                                ║░▓▓▓▓▓
  239. ECHO ▓▓▓▓▓▓▓╚════════════════════════════════════════════════════════════════╝░▓▓▓▓▓
  240. ECHO ▓▓▓▓▓▓▓▓▓░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░▓▓▓▓▓
  241. ECHO ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
  242. ECHO ═══════════════════════════════════════════════════════════════════════════════
  243. RETURN
  244. *====================== End Sub routine: PROC_DISEAS ========================== 
  245.